dnl  Make release version numbers match /^[0-9.]*$/
dnl  Experimental ones are ...x, and betas are ...bn
AC_INIT(jason, 0.2x, norman@astro.gla.ac.uk)
AC_DEFINE(RELEASE_DATE, "2013 XXX XX", [Release date of the current version])

AC_SUBST(LIBRARY_HOMEPAGE, [http://bitbucket.org/nxg/jason])

dnl  Embed a snapshot identifier in the binary, if it's not a release version
if expr $PACKAGE_VERSION : ['[0-9.]*$'] >/dev/null; then
    # release version: empty string identifies release version
    SNAPSHOTID=""
else
    SNAPSHOTID="`hg id`"
fi
AC_DEFINE_UNQUOTED([SNAPSHOTID],
                   ["$SNAPSHOTID"],
                   [Description of snapshot, or blank if release version])
PACKAGE_VERSION_INTEGER=[`echo ${PACKAGE_VERSION}-0 | awk -F'[^0-9]*' '{printf "%d 1000000* %d 1000* %d++p", $1,$2,$3}' | dc`]
AC_SUBST(PACKAGE_VERSION_INTEGER)
AC_DEFINE_UNQUOTED([PACKAGE_VERSION_INTEGER],
                   [$PACKAGE_VERSION_INTEGER],
                   [Version number as an integer: major*1e6+minor*1e3+release])

AC_CONFIG_AUX_DIR([m4])  dnl tidy these away
AC_CONFIG_HEADERS([src/config.h])

AM_INIT_AUTOMAKE
LT_INIT
AC_CONFIG_MACRO_DIR([m4])
AM_SILENT_RULES([yes])  dnl add V=1 to make to get chatter back

AC_CONFIG_SRCDIR(README.md)

AC_C_BIGENDIAN

AC_PROG_CC

AC_PROG_LEX
AC_PATH_PROG(BISON, bison)
dnl  AC_PROG_YACC

dnl  Output
AC_CONFIG_FILES([Makefile src/Makefile src/test/Makefile])

AC_OUTPUT